Die Meteorbahn innerhalb der Erdatmosphäre

Die Reduktion des in der Erdatmosphäre aufleuchtenden Bahnteils, entspricht beobachtungstechnisch der Bahnbestimmung von nahen Erdsatelliten aus 3 Richtungsmessungen  (»Range and Range Rate«).

Mindestens zwei Richtungswinkel (Parallaxen) zweier weit entfernter Beobachtungsstationen müssen für eine Bahnbestimmung vorliegen, besser drei, um den Radianten auch in dem Fall berechnen zu können, wenn die Flugbahn auf dem durch zwei Stationen verlaufenden Großkreisbogen liegen sollte. Die Stationen können z. B. die östliche u. westliche und die dritte die südliche oder nördliche Spitze eines gleichseitigen Dreiecks bilden, wobei die Basislänge etwa 40 bis 80 km betragen sollte. Das direkt auf eine Station zufliegende Meteor erscheint stationär.

Bei simultanen photographischen Aufnahmen von zwei, besser drei oder n-Stationen, sind die Stationskameras auf den gemeinsamen Schnittpunkt am Himmel in der mittleren Aufleuchthöhe (etwa 90-110 km) der Meteore zu richten (Fig. 30), d.h. auf den Radianten, der über >40° Höhe einnehmen sollte, oder nahe gelegene Sternbilder. Das günstigste Verhältnis von Bahnlänge und Geschwindigkeit erreichen Meteore allerdings in etwa 45 Grad Abstand vom Radianten, so daß die Kameras etwa diesen Winkel mit den Radianten einnehmen sollten. Die verschiedenen Richtungswinkel (Parallaxen) der optischen Kamerachsen sind daher genau genommen trigonometrisch festzulegen.

Angenommen, die Stationen A,B,C verfügen über je 3 Kameras [A(i),B(i),C(i), i=1,2,3], deren optische Achsen A(1) in Azimut 310°, Höhe 40°, A(2) Azimut 1°, Höhe 50°, A(3) Azimut 50°, Höhe 40° ausgerichtet werden sollen. Die Ausrichtung in Azimut ist mit einem Kompaß [Nadel-Mißweisung zwischem magnet. u. geograph. Nordpol in Deutschland -4 Grad] und die Höhe mit einem Winkelmesser zu bewerkstelligen, oder läßt sich am berechneten Azimut und Höhe stellarer Objekte des Himmelsglobus  feststellen.

Folg. Programm TRIAN berechnet die topozentrischen Koordinaten des Punktes, auf den die opt. Kameraachsen auszurichten sind. Die mittl. Aufleucht- u. Verlöschhöhe der Meteore (hm), ist so zu wählen, daß der für die zweite Station berechnete topozentrische Bahnweg des Meteors ebenfalls (wie die der ersten Station) durch den Radianten führt.

REM GFA36 PROGR. TRIAN
DIM b(10),gzb(10),ro(10),l(10),osz(10),kh(10),ka(10),dek(10),ar(10),gdek(10),gar(10),tdek(10),tar(10),del(10),rg(10),rt(10),t(10),th(10),taz(10)
DEFFN r(x) = x - INT(x / (2 * PI)) * (2 * PI)
DEFFN gzb(x) = ATN(1 / (1 + 0.006739501819 * (6378140 / (6378140 + eh))) * TAN(x))
DEFFN ro(x) = 6356.755288158 / SQR(1 - 0.006694384999592 * COS(FN gzb(x)) ^ 2) + eh / 1000
REM ---------------- FORMATION - ORTSKONSTANTEN -------------
REM STATION A
eh = 41  //EINTRAG AUSGESHÖHE DES BEOBACHTERS ÜBER N.N. IN METERN STATION A
b(1) = RAD(50 + 31 / 60 + 30.12 / 3600)  //EINTRAG GEOGRAPHISCHE BREITE (°,','') STATION A
gzb(1) = FN gzb(b(1))   //GEOZENTRISCHE BREITE DER BEOBACHTUNGSSTATION A
ro(1) = FN ro(b(1))  //ENTFERNUNG DER STATION A + HÖHE NN VOM ERDMITTELPUNKT IN KM
l(1) = (7 + 48 / 60 + 32.21 / 3600) //EINTRAG GEOGRAPHISCHE LNGE (°,','') DER BEOBACHTUNGSSTATION A IN GRAD
REM STATION B
eh = 65                         //N.N. 65 m
b(2) = RAD(50 + 30 / 60 + 19.53 / 3600)  //+50°30'19.53'' n. Br.
gzb(2) = FN gzb(b(2))
ro(2) = FN ro(b(2))
l(2) = (8 + 18 / 60 + 11.34 / 3600)             //+8°18'11.34'' " ö. L.
REM STATION C
eh = 100
b(3) = RAD(50 + 20 / 60 + 11.1 / 3600)
gzb(3) = FN gzb(b(3))
ro(3) = FN ro(b(3))
l(3) = (7 + 55 / 60 + 11.23 / 3600)
REM EINTRAG DATUM -------------------
a4 = 1989   //EINTRAG JAHR
a3 = 1      //EINTRAG MONAT
a2 = 1      //EINTRAG TAG
GOSUB jd
t1 = (jd - 2451545) / 36525
REM EINTRAG UHRZEIT (UT = h,m,s) -------------
ut = 22 + 30 / 60 + 45 / 3600
t = (jd + ut / 24 - 2451545) / 36525
l = l(1) //ORTSSTERNZEIT STATION A
GOSUB osz
osz(1) = osz
l = l(2) //ORTSSTERNZEIT STATION B
GOSUB osz
osz(2) = osz
ll = l(3) //ORTSSTERNZEIT STATION C
GOSUB osz
osz(3) = osz
REM TOPOZENTRISCHE KAMERAAUSRICHTUNG STATION A ZUM ZEITPUNKT UT
kan = 3          //EINTRAG KAMERA-ANZAHL
kh(1) = RAD(40)  //EINTRAG HÖHE   KAMERA 1 STATION A
ka(1) = RAD(310) //EINTRAG AZIMUT KAMERA 1 (AZIMUT AB SšDEN
kh(2) = RAD(50)  //EINTRAG HÖHE   KAMERA 2 ÜBER WESTEN
ka(2) = RAD(1)   //EINTRAG AZIMUT KAMERA 2 0...360 GRAD)
kh(3) = RAD(40)  //EINTRAG HÖHE   KAMERA 3
ka(3) = RAD(50)  //EINTRAG AZIMUT KAMERA 3
REM TRANSFORMATION TOPOZENTR. HORIZONTAL- IN TOPOZENTR. ÄQUATORIALSYSTEM STATION A
FOR i = 1 TO kan
  dek(i) = ASIN(SIN(b(1)) * SIN(kh(i)) - COS(b(1)) * COS(kh(i)) * COS(ka(i))) //DEKLINATION
  x = (COS(b(1)) * SIN(kh(i)) + SIN(b(1)) * COS(kh(i)) * COS(ka(i))) / COS(dek(i))
  y = COS(kh(i)) * SIN(ka(i)) / COS(dek(i))
  IF x <= -1 THEN
    t(i) = PI  //TOPOZENTR. STUNDENWINKEL
  ELSE
    t(i) = FN r(ATN(y / (1 + x)) * 2)
  ENDIF
  ar(i) = FN r(osz(1) - t(i)) //TOPOPZENTR. REKTASZENSION
NEXT i
REM EINTRAG MITTLERE HÖHE (km) DER METEORE hm (km)----
hm = 100  //Z.B. PERSEIDEN MITTL. AUFLEUCHTHÖHE 115 KM, VERLÖSCHHÖHE 95 KM; LEONIDEN 126 KM, 94 KM
r = ro(1) + hm
REM TRANSFORMATION TOPOZENTR. ÄQUATORIAL IN GEOZENTR. ÄQUATORIAL STATION A
FOR i = 1 TO kan
  DO
    ss1 = rg(i)
    del(i)=SQR(r^2+ro(1)^2-2*r*ro(1)*(COS(gdek(i))*COS(gar(i)-osz(1))*COS(gzb(1))+SIN(gdek(i))*SIN(gzb(1)))) //TOPOZENTR. ENTFERNUNG
    x = del(i) * COS(dek(i)) * COS(ar(i)) + ro(1) * COS(gzb(1)) * COS(osz(1))
    y = del(i) * COS(dek(i)) * SIN(ar(i)) + ro(1) * COS(gzb(1)) * SIN(osz(1))
    z = del(i) * SIN(dek(i)) + ro(1) * SIN(gzb(1))
    rg(i) = SQR(x * x + y * y + z * z)
    ss = z / rg(i)
    IF ABS(ss) < 1 THEN
      gdek(i) = ASIN(ss) //GEOZENTRISCHE DEKLINATION STATION A
    ENDIF
    x = x / (rg(i) * COS(gdek(i)))
    y = y / (rg(i) * COS(gdek(i)))
    IF x =< -1 THEN
      gar(i) = PI //GEOZENTRISCHE REKTASZENSION STATION A
    ELSE
      gar(i) = FN r(ATN(y / (1 + x)) * 2)
    ENDIF
    IF ABS(rg(i) - ss1) < 0.0001 THEN
      GOTO in
    ENDIF
  LOOP
  in:
NEXT i
REM DIE GESICHTSFELDMITTE (OPT. ACHSE) DER STATIONSKAMERAS A,B,C AUF FOLG. KOORDINATEN AUSRICHTEN
REM TOPOZENTR. HÖHE (h) ,AZIMUT (Az), TOPOZENTR. DEKLIN. (dek), AR, GEOZENTR. u. TOPOZENTR: ENTF. r,del
PRINT "STATION A: Geograph. Breite: ";ROUND(DEG(b(1)),7);", Länge: ";ROUND(l(1),7);" Grad"
n = 1
FOR i = 1 TO kan
  n = n + 1
  PRINT AT(1,n);"KAMERA ";i;": h ";ROUND(DEG(kh(i)),3);", Az ";ROUND(DEG(ka(i)),3);", dek ";ROUND(DEG(dek(i)),3);", AR ";ROUND(DEG(ar(i)),3);", r ";ROUND(rg(i),1);" km, del ";ROUND(del(i),1);" km"
NEXT i
REM TRANSFORMATION GEOZENTRISCH ÄQUATORIAL ZU TOPOZENTR. ÄQUATORIAL UND TOPOZENTR. HORIZONTAL
REM STATION B
i1 = 2
GOSUB conv
PRINT "STATION B: Geograph. Breite: ";ROUND(DEG(b(2)),7);", Länge: ";ROUND(l(2),7);" Grad"
n = n + 1
FOR i = 1 TO kan
  n = n + 1
  PRINT AT(1,n);"KAMERA ";i;": h ";ROUND(DEG(th(i)),3);", Az ";ROUND(DEG(taz(i)),3);", dek ";ROUND(DEG(tdek(i)),3);", AR ";ROUND(DEG(tar(i)),3);", r ";ROUND(rg(i),1);" km, del ";ROUND(rt(i),1);" km"
NEXT i
REM STATION C
i1 = 3
GOSUB conv
PRINT "STATION C: Geograph. Breite: ";ROUND(DEG(b(3)),7);", Länge: ";ROUND(l(3),7);" Grad"
n = n + 1
FOR i = 1 TO kan
  n = n + 1
  PRINT AT(1,n);"KAMERA ";i;": h ";ROUND(DEG(th(i)),3);", Az ";ROUND(DEG(taz(i)),3);", dek ";ROUND(DEG(tdek(i)),3);", AR ";ROUND(DEG(tar(i)),3);", r";ROUND(rg(i),1);" km , del ";ROUND(rt(i),1);", km"
NEXT i
KEYGET HALT%
END
PROCEDURE conv
  FOR i = 1 TO kan
    x = rg(i) * COS(gdek(i)) * COS(gar(i)) - ro(i1) * COS(gzb(i1)) * COS(osz(i1))
    y = rg(i) * COS(gdek(i)) * SIN(gar(i)) - ro(i1) * COS(gzb(i1)) * SIN(osz(i1))
    z = rg(i) * SIN(gdek(i)) - ro(i1) * SIN(gzb(i1))
    rt(i) = SQR(x * x + y * y + z * z)
    tdek(i) = ASIN(z / rt(i)) //TOPOZENTR. DEKLINATION hm=90 km
    x = x / (rt(i) * COS(tdek(i)))
    y = y / (rt(i) * COS(tdek(i)))
    IF x =< -1 THEN
      tar(i) = PI //TOPOZENTRISCHE REKTASZENSION hm=90 km
    ELSE
      tar(i) = FN r(ATN(y / (1 + x)) * 2)
    ENDIF
    th(i) = ASIN(SIN(b(i1)) * SIN(tdek(i)) + COS(b(i1)) * COS(tdek(i)) * COS(osz(i1) - tar(i)))  //TOPOZENTR. HÖHE
    x = (-COS(b(i1)) * SIN(tdek(i)) + SIN(b(i1)) * COS(tdek(i)) * COS(osz(i1) - tar(i))) / COS(th(i))
    y = (COS(tdek(i)) * SIN(osz(i1) - tar(i))) / COS(th(i))
    IF x =< -1 THEN
      taz(i) = PI //TOPOZENTR. AZIMUT
    ELSE
      taz(i) = FN r(ATN(y / (1 + x)) * 2)
    ENDIF
  NEXT i
RETURN
PROCEDURE jd
  jd = 1720996.5 + a2 + FIX(30.6001 * ((a3 - 12 * (a3 < 3)) + 1)) + FIX(365.2425 * (a4 + (a3 < 3)))
RETURN
PROCEDURE osz
  f8 = 6.697374558333 + 2400 * t1 + 0.05133690722222 * t1
  f8 = f8 - INT(f8 / 24) * 24
  f9 = f8 + ut * 1.002737909
  sz = f9 - INT(f9 / 24) * 24
  osz = RAD(sz * 15)
RETURN



Sub-Meteor Ort (Groundtrack)

An den verschiedenen Beobachtungsstationen werden lediglich die topozentrischen Richtungswinkel der Meteorspuren photographisch dokumentiert. Auf dem Wege der photographischen Ortsbestimmung ergib die ausgemessene Querdimension des Meteors die äquatorialen Polarkoordinaten (a, d) - meist interessiert nur der Aufleucht- u. Verlöschpunkt der Meteorspur (s. Progr. ASTROGRAPH I u. II).

METHODE I (Vektordarstellung)

Geozentrische Koordinaten der Stationen:

Geozentrische Breite Standort
DEFFN gzb(x)=ATN(1/(1+0.006739501819*(6378140/(6378140+eh)))*TAN(x))
Entfernung Geozentrum-Standtort
DEFFN ro(x)=6356.755288158/SQR(1-0.006694384999592*COS(FN gzb(x))^2)+eh/1000
Geozentr. Breite in geographische Breite
DEFFN ggb(x)=ATN((1+0.006739501819*(6378140/(6378140+eh)))*TAN(x))

b1=FN gzb(b1), r1=FN ro(b1); b1,l1,r1 ,b2,l2,r2=geozentrische Breite, Länge, Entfernung u. eh=Höhe der Stationen über N.N. (Normalnull) in Meter.

x1=r1 cos(b1) cos(l1)  ‘
y 1=r1 cos(b1) sin(l1)   
z1=r1 sin(b1)          

x2=r2 cos(b2 ) cos(l2)
y2=r2 cos(b2) sin(l2)
z2=r2 sin(b2)

Geozentrischer Vektor av = Å (x12+y12+z12) Station A
Geozentrischer Vektor bv = Å(x22+y22+z22) Station B
Differenz bv-av:
dx=x2-x1    (Fig. 30)
dy=y2-y1
dz=z2-z1

Da die Koordinaten (d=Deklin., ar=AR) des gleichen Punktes der scheinbaren Meteorbahn zweier oder n-Stationen durch photographische Ortsbestimmungen vorliegen, ergeben sich die entsprechenden topozentrischen Entfernungen durch deren Iteration.

de, are, dave u. dbe = auf Station A bezogene topozentrische Deklin., AR und Entfernung des Punktes; auf Station  B bezogende dbe, arbe, dbve = topozentrische Deklination, Rektaszension u. Entfernung des Punktes - meist Anfang-/Endpunkt der Meteorspur); gsz = Sternzeit in Greenwich (=geographische Länge = 0) zu der das Meteor den Punkt der Bahn passierte (Weltzeit UT).

dbve=0 
dao=de
arao=are
REPEAT //Bedingte Schleife ITERATION dbve
x=dbve cos(dbe) cos(arbe-gsz) //Richtungswinkel Station B
y=dbve cos(dbe) sin(arbe-gsz)
z=dbve sin(dbe)
x3=dx+x
y3=dy+y
z3=dz+z
dave=Å(x32+y32+z32) //dave Entfernung Bahnpunkt Station A
de1=arcsin(z3/dave)
x=x3/(dave cos(de1))
y=y3/(dave cos(de1))
are1= FN r(ATN(y/(1+x))*2+gsz) //Richtungswinkel Bahnpunkt Station A
ww=DEG(ABS(are1-arao))
dbve=dbve+ww    //dbve = Entfernung Endpunkt von Station B
UNTIL ww<1E-10 //Schleife
Topozentrischer Vektor dav=Å(x32+y32+z32 ) Station A (Fig. 30)
Topozentrischer Vektor dbv=Å(x2+y2+z2 ) Station B.

Die Iteration der Entfernung »dbve« bricht ab (ww<1E-10), wenn die iterierte topozentrischer Koordinate (de,are) der Meteorspur und die zuvor auf photographischem Wege gemessene (dao,arao) der Station A übereinstimmen (dao=de1=de, arao=are=are1). Der Wert »dave« und »dbve« bildet somit die topozentrische Entfernung des gewählten Meteorspurpunktes (z. B. Verlöschpunkt de, are in A und dbe, arbe in B) der Station A und B.



Sub-Meteor Ort des gewählten Punktes (de,are) der Meteorbahn

gx = r1 cos(b1) cos(l1)+dave cos(da) cos(are - gsz)
gy = r1 cos(b1 )  sin(l1 )+dave cos(de) sin(are - gsz)
gz = r1 sin(b1)             + dave SIN(de)
gd=Å (gx2+gy2+gz2) //geozentrischer Vektor des Meteorpunktes gd(de,are)
gdek=arcsin(gz/gd)
x=x3/(gd cos(gdek))
y=y3/(gd cos(gdek))
gar= FN r(ATN(y/(1+x))*2)

gdek, gar, gd = geozentrische (auf den Erdmittelpunkt bezogene) Breite, Länge und Entfernung des gewählten Sub-Meteor Punktes (de,are) der scheinbaren Meteorbahn.

Geographische Breite (gb) des Sub-Meteor Orts mit Meteor am Zenit: gb=FN ggb(gdek).
Abstand (gr) des Sub-Meteor Punktes von der Erdmitte: gr=FN ro(gdek).
Höhe (Hm) des gewählten Sub-Meteor Punkts über Seehöhe (eh =0) bzw. N.N.: Hm=gd-gr.

Die topozentrische Entfernungen, Geschwindigkeitskomponenten eines künstlichen Erdsatelliten, die geozentrische Breite und Länge seines Sub-Satelliten Orts, werden analog berechnet.

Der Abschnitt TRANSFORMATION TOPOZENTRISCH ÄQUATORIAL IN GEOZENTRISCH ÄQUATORIAL. Das Progr. TRIAN liefert ebenfalls die geograph. Breite und Länge des Sub-Meteor Punktes.

Geographische Breite (lat) des Sub-Meteor Punktes unter Berücksichtigung der Erdablattung. br=gdek= (=geozentrische Breite=Deklination), r=gd=md (=geozentrische Entfernung des Meteors).

FOR i=1 TO 10 
gr=6378.137*SQR(0.993305615/(1-0.006694385*COS(d1)^2))+eh/1000
lat=ATN(1.00673950182*TAN(d1))
h=SQR(gr^2-gr^2*SIN(lat-d1)^2)-gr*COS(lat-d1)
d1=br-ASIN((h/r)*SIN(lat-d1))
NEXT i
PRINT DEG(lat) //=geograpische Breite des Sub-Meteor Punktes
PRINT DEG(d1)  //=geozentrische Breite des Sub-Meteor Punktes
PRINT h  //Höhe des Sub-Meteor Punkts über N.N. (eh)

Die in eine Erdkarte eingetragene geographische Breite und Länge des Sub-Meteor Aufleucht- u. Verlöschpunktes, verbunden zu einer Strecke, bildet den Groundtrack der Bahn.

Aufleucht- bzw. Anfangspunkt einer Intervallänge (Ln ) der mit Shutter zerhackten Meteorspur (da,ara,dava=Deklin., Rektaszension und Entfernung von Station A):

lxa = r1 cos(b1) cos(l1) + dava cos(da) cos(ara - gsz)
lya = r1 cos(b 1) sin(l1) + dava cos(da) sin(ara - gsz)
lza = r1 sin(b1)             +dava SIN(da)

Verlösch- bzw. Endpunkt  Intervallänge der zerhackten Meteorspur (de,are,dave=Deklin, Rektaszension u. Entfernung Station A):

lxe = r1 cos(b1) cos(l1)+dave cos(de) cos(are - gsz)
lye = r1 cos(b1) sin(l1)+dave cos(de) sin(are - gsz)
lze = r1 sin(b1)            +dave SIN(de)

Differenz:
lx=lxa-lxe
ly=lya-lye
lz=lza-lze
L=Å(lx2+ly2+lz2)

»L« (km) ist die wahre Weglänge des in der Erdatmosphäre sichtbaren Bahnstücks (Aufleucht- u. Verlöschpunkt) bzw. Länge einzelner n-Segmente (Ln) der zerhackten Meteorspur. Die Berechnung der wahren Weglänge (Ln = [H1-H2]/cos ZR) aus der Höhe (Hn) eines Trajektoriepunktes über der Horizontebene einer Station (Fig. 31) erübrigt sich dadurch.

An der durch den Shutter in kurze Zeitintervalle (Segmente) zerhackten Bahnspur,  läßt sich die jeweilige Geschwindigkeit (vo) und Verlangsamung eines Meteors an einem beliebigen Bahnpunkt feststellen, wenn die jeweilige Länge (km) eines Segmentes (Ln) durch das Zeitintervall des Shutters (dt) dividiert wird. Die Verlangsamung (dv/dt) ergibt sich aus der Länge eines Segments (vo1=L1/dt, v o2=L2/dt usw.) gegenüber dem folgenden (dv/dt=vo2-vo1).

Ist Hma und Hme die entsprechende N.N.-Höhe des Meteors am Anfang- und Endpunkt der Bahnspur, ergibt sich die genäherte Neigung der Trajektorie gegen die durch die Station A und B verlaufene Ebene aus: arcsin W=(Hma-Hme)/L. Fig. 31. Grundlage sämtlicher berechneter Koordinaten ist hierbei das Äquinoktium des Datums..



METHODE II (trigonometrischer Ansatz).

gzb=FN gzb(b), r=FN ro(b); gzb,b,l,r=geozentrische, geographische Breite, Länge, Entfernung vom Geozentrum u. eh=Höhe der Stationen über N.N. in Meter. de,are=Deklination und Rektaszension des Endpunktes der Meteorspur aufgrund photographischer Ortsbestimmungen der Beobachtungsstationen; h,az=scheinbare Höhe u. Azimut des Endpunktes (zu berechnen aus de, are); osz=Ortssternzeit der jeweiligen Station.

 arcsin h=sin(b)*sin(de)+cos(b)*cos(de)*cos(osz-are)
cos(h) sin(az)=cos(de) sin(osz-are)
cos(h) cos(az)=-cos(b) sin(de)+sin(b) cos(de) cos(osz-are)
(Azimut zählt ab Süden über Westen 0<=az<=360 Grad).

de,are=Deklination und Rektaszension eines beliebigen Punktes oder des Aufleuchtpunktes der Meteorspur. Hme=lineare Höhe über N.N. des Endpunktes (Ort mit dem aufleuchtenden oder verlöschenden Meteor am Zenit = Sub-Meteor Punkt).
Die beobachteten oder berechneten Azimute des Endpunktes der Meteorspur aller Stationen sind  hier zur Ermittlung der geographischen Breite und Länge des Endpunktes (Sub-Meteor Punkt) heranzuziehen.

P=Nordpol des Himmelsäquators (Fig. 32); j,n=Winkel und geographische Länge der Schnittpunkte der beobachteten Azimutallinien mit dem Himmels- bzw. Erdäquator; m=am Stationsort S beobachtetes Azimut (az) des Endpunktes m der Meteorspur; b,l=geographische Breite und Länge der Station S; A=Pol der Azimutallinie; bm,lm=geographische Breite und Länge des Endpunktes der Meteorspur (Sub-Meteor Punkt).
Die wahrscheinlichste geographische Lage bm,lm des Endpunktes einer größeren Anzahl Azimute ist jene, für welche die Fehlerquadratsumme der sphärischen Lote M-m auf die beobachteten Azimutallinien ein Minimum annehmen (Fig. 32).

In dem sphärischen Dreieck mit den drei Punkten P,n und S findet man die Beziehung:

sin(j) sin(le-k)=sin(az) sin(b)
sin(j) cos(le-k)=cos(az)
cos(j)=sin(az) cos(b)

x=cos(az)
y=sin(az)*sin(b)
j=SQR(x^2+y^2)
x=x/j
y=y/j
k=FN r(le-ATN(y/(1+x))*2) //b,le=geographische Breite u. Länge der Station
j=asin(j)
xo=ctg(bm) cos(lm)
yo=ctg(bm) sin(lm)
s=SQR(xo^2+yo^2)
x=xo/s
y=yo/s
lm=FN r(ATN(y/(1+x))*2)
bm=atn(1/s)
xo sin(k) sin(j) - yo cos(k) sin(j) + cos(j) = 0

Gleich:
xo sin(k) sin(j) - yo cos(k) sin(j) = -cos(j)
Gleich:
xo sin(k) sin(j) - yo cos(k) sin(j) = de-cos(j) //de=Deklination des Endpunktes der Meteorspur

Bei nur 2 Beobachtungsorten werden 2 lineare Gleichungen mit zwei Unbekannten (xa-yb+c=0) streng aufgelöst:

REM GFA37 GLEICHUNGAUFLÖSUNG MIT ZWEI UNBEKANNTEN a1 x - b1 y = r1
REM                                a2 x - b2 y = r2
REM EINTRAG KOEFFIZIENTEN a,b; UBEKANNTE x,y
a1 = 10
a2 = 40
b1 = 100
b2 = 30
REM EINRAG RESIDUEN
r1 = -4970
r2 = -1380
REM -----------------
d = a1 * b2 - a2 * b1
IF d <> 0 THEN
  x = (b2 * r1 - b1 * r2) / d
  y = (a2 * r1 - a1 * r2) / d
  PRINT "UNBEKANNTE x,y"
  PRINT "x ";x
  PRINT "y ";y
  PRINT "PROBE"
  PRINT a1 * x - b1 * y;"= ";r1
  PRINT a2 * x - b2 * y;" = ";r2
ELSE
  PRINT "GLEICHUNG NICHT AUFLÖSBAR"
  END
ENDIF
STOP

 

REM GFA38  BASIC PROGR. FÜR WINDOWS 3.1/95
REM GLEICHUNG MIT DREI UNBEKANNTEN a1 x + b1 y + c1 z = r1
REM                                a2 x + b2 y + c2 z = r2
REM                                a3 x + b3 y + c3 z = r3
REM EINTRAG KOEFFIZIENTEN a,b,c
a1 = 1.1
a2 = 3
a3 = 10
b1 = 2
b2 = 2.5
b3 = 3
c1 = 10000
c2 = 500.9
c3 = 30.991
REM EINTRAG RESIDUEN ------------
r1 = 50203.3
r2 = 2763.5
r3 = 484.955
REM ---------------------
d = a1 * b2 * c3 + a2 * b3 * c1 + a3 * b1 * c2 - a3 * b2 * c1 - a1 * b3 * c2 - a2 * b1 * c3
IF d <> 0 THEN
  x = (b1 * c2 * r3 + b2 * c3 * r1 + b3 * c1 * r2 - b2 * c1 * r3 - b3 * c2 * r1 - b1 * c3 * r2) / d
  y = (a1 * c3 * r2 + a2 * c1 * r3 + a3 * c2 * r1 - a3 * c1 * r2 - a1 * c2 * r3 - a2 * c3 * r1) / d
  z = (a1 * b2 * r3 + a2 * b3 * r1 + a3 * b1 * r2 - a3 * b2 * r1 - a1 * b3 * r2 - a2 * b1 * r3) / d
  PRINT "UNBEKANNTE x,y,z:"
  PRINT ''x '';x
  PRINT ''y '';y
  PRINT ''z '';z
  PRINT "PROBE"
  PRINT a1 * x + b1 * y + c1 * z;" = ";r1
  PRINT a2 * x + b2 * y + c2 * z;" = ";r2
  PRINT a3 * x + b3 * y + c3 * z;" = ";r3
ELSE
  PRINT "GLEICHUNG NICHT AUFLÖSBAR"
  END
ENDIF
STOP


Liegen Azimute einer größeren Anzahl Beobachtungsorte vor, ist der wahrscheinlichste Wert nach der Methode der kleinsten Fehlerquadratsumme zu ermitteln.

Normalgleichung für zwei Unbekannte xo,yo:

a(n) =  sin(k(n)) sin(j(n))
b(n) = -cos(k(n)) sin(j(n))
c(n) = -cos(j(n))  (n=1,2,3...)

Die Gleichungssysteme haben die Anzahl der Beobachtungsstationen.

Akkumulation:
[a2] =  S a(1)*a(1)+a(2)*a(2)+a(3)*a(3)...
[ab] = S a(1)*b(1)+a(2)*b(2)+a(3)*b(3)...
[b2] = S b(1)*b(1)+b(2)*b(2)+b(3)*b(3)...
[ac] = S a(1)*c(1)+a(2)*c(2)+a(3)*c(3)...
[bc] = S b(1)*c(1)+b(2)*c(2)+b(3)*c(3)...

Normalgleichung:
[a2] xo + [ab] yo = [ac]
[ab] xo + [b2] yo = [bc]

Lineare Höhe (Hme) des Endpunktes der Meteorspur über der Erdoberfläche. Höhe und Azimut des Endpunktes der Meteorspur (dme) entweder mit Theodolit unmittelbar an der Sphäre messen, Bahnspur in eine Sternkarte einzeichnen und die gesuchten Koordinaten daraus entnehmen, oder nach der genauen Methode der photographischen Ortsbestimmung berechnen. Ist daraus der Höhenwinkel h des Endpunktes dme an einer Station bekannt geworden, findet man die lineare Höhe Hme aus den Beziehungen am ebenen Dreieck zwischen Erdmitte O, dme und der Station S. Winkel am Geozentrum O zwischen der Station S und dem Sub-Meteor Ort Me (bm,lm) bzw. dem Endpunkt dme (Fig. 33):

cos u=sin(b) sin(bm) + cos(b) cos(bm) cos(l-lm).
rs/(rs+Hme)=cos(h)/cos(h+u).
arctan h=(1/tan(u))-(rs/(rs+Hme))*(1/sin(u)).
Hme=2*rs*sin(0.5*u)*(sin(h+0.5*u)/cos(h+u)).

Quadratische Gleichung:
dmev2+2*rs*SIN(h)*dmev+(rs2-(rs+Hme)2)=0.
Auflösung: a=2*rs*sin(h); b=rs2-(rs+Hme)2.
dmev=-a/2+ Å(a2/4-b).

h=Höhenwinkel, rs=jeweilige geozentrische Entfernung (km) der Station S vom Erdmittelpunkt O (oder rs=6378.14 km Erdäquatorradius); bm,lm=geographische Br. u. Länge des Sub-Meteor Orts (Me); b,l=geographische Br. u. Länge einer Station (S); dmev=topozentrische Entfernung des Endpunktes (dme), gesehen von der Station S; u=Zentriwinkel des Großkreisbogens S-Me (Fig. 33).

Ausgehend von den geographischen Koordinaten (bm,lm,rme=FN ro(bm) = geographische Breite, Länge u. geozentrische Entfernung) des Sub-Meteor Punktes (Me) und der linearen Höhe Hme des Endpunktes der Meteorspur, ergeben sich endlich die topozentrischen äquatorialen Koordinaten des Endpunktes (dme) einer Station.

bm,gzbm,=geographische, geozentrische Breite, lm=geographische Länge Endpunkt dme; oszm=Ortssternzeit des Sub-Meteor Punktes Me bzw. dme (Fig. 33); oszs=Ortssternzeit einer Station; rs=Erdradius (6378.14 m) oder geozentrische Entfernung einer Station S zum Geozentrum O (geometr. Ermittelpunkt); b,gzbs=geographische oder geozentrische Breite einer Station.

x=(rme+Hme) cos(gzbm) cos(oszm-oszs)-rs*cos(bs)
y=(rme+Hme) cos(gzbm) sin(oszm-oszs)
z=(rme+Hme) sin(gzbm)-rs sin(bs)
dmve=SQR(x^2+y^2+z^2)
ds=ASIN(z/dmev)
x=x/(dmev*cos(ds))
y=y/(dmev*cos(ds))
ars=FN r(lm-ATN(y/(1+x))*2)

ds,ars,dmev=topozentr. Deklination, Rektaszension und Entfernung des Endpunktes (dme), gesehen von der Station S (Fig. 33).

Lineare Länge (L) der Bahn innerhalb der Erdatmosphäre.
cos sw = sin(de) sin(da) + cos(de) cos(da) cos(are-ara)
cos dmw = -sin(dr) sin(de) - cos(dr) cos(de) cos(arr-are)

da,ara,de,are=Deklin. u. Rektaszension (AR) des Anfangs- und Endpunktes der Meteorspur; L=wahre Länge der Meteorspur (km) zwischen den beobachteten Bahnpunkten; S=Beobachtungsstation; sw=Bogen zwischen Anfang- u. Endpunkt der in S beobachteten scheinbaren Bahn (Fig. 34); dmw=Winkel am Endpunkt der Meteorspur zwischen der Richtung zum Radiationspunkt R und der Station S.

dr,arr=Deklination u. Rektaszension des unkorrigierten scheinbaren Radianten (Radiantenberechnung dr,arr); dmav,dmev=topozentrische Entfernung des Anfangs- u. Endpunktes dma/dme von der Station S (Fig. 34).

Wahre Länge L (Strecke dma-dme): L (km) = (dmev sin(sw))/sin(sw+dmw). Die bereits zuvor ermittelte topozentrische Entfernung dmev ergibt sich auch aus der quadratischen Gleichung:

(rs+Hme)2 = dmev2 + dmev 2 rs sin(h) + rs2 (h, Hm und rs Fig. 33).
ao=rs^2; a1=2*rs*SIN(h); y=(rs+Hme)^2; dmev=-a1/2+SQR(a1^2/4-(ao-y)).
Entfernung dmav (km) = (dmev sin(dmw))/sin(sw+dmw)

Geographische Koordinate des Sub-Meteor Anfangspunktes (dma Fig. 35):
hre=asin(sin(gzbm)*sin(dr)+cos(gzbm)*cos(dr)*cos(oszm-arr))
y=(cos(dr) sin(oszm-arr))/cos(hre)
x=(-cos(gzbm) sin(dr)+sin(gzbm) cos(dr) cos(oszm-arr))/cos(hre)
azre=FN r(ATN(y/(1+x))*2).

Azimut azre zählt ab Süden über Westen 0<=az<=360 Grad; dr,arr=Deklin., AR des Radianten; gzbm,oszm=geozentrische Breite u. Ortssternzeit des Endpunktes (dme); hre,azre=Höhe und Azimut des scheinbaren Radianten für den geographischen Ort des Sub-Meteor Endpunktes der Bahn (dme, Me).

He=rme+Hme (Fig. 33,35). arctan i=(L cos(hre))/(He+L sin(hre)).

Ha=(L cos(hre))/sin(i); He=(L cos(hre+i))/sin(i).

o=Ha-He; o=(L/sin(i))*(cos(hre)-cos(hre+i)); o=(L sin(hre+0.5*i))/cos(0.5*i); Hma=Hme+o; Hma=Höhe des Anfangspunktes der Meteorspur über der Erdoberfläche bzw. N.N.

gzbma=asin(cos(i) sin(gzbm) - sin(i) cos(gzbm) cos(azre))

x=(cos(i) cos(gzbm) + sin(i) sin(gzbm) cos(azre))/cos(gzbma)
y=(sin(i) sin(azre))/cos(gzbma)
lma=FN r(ATN(y/(1+x))*2)

gzbma,lma=geozentriche Breite u. Länge des Aufleuchtpunktes (dma) der Meteorspur (Fig. 35).

Alle Rechte vorbehalten (all rights reserved) , auch die der fotomechanischen Wiedergabe und der Speicherung in elektronischen Medien, Translation usw. Dasselbe gilt für das Recht der öffentlichen Wiedergabe. Copyright © by H. Schumacher, Spaceglobe

Sternbeobachter - Sterntagebuch - Produktinformation - www.spaceglobe.de